Wikipedija

Datoteka:QuantumHarmonicOscillatorAnimation.gif

QuantumHarmonicOscillatorAnimation.gif ‎(300 × 373 piksela, veličina datoteke/fajla: 759 kB, MIME tip: image/gif, stalno iznova, 97 sličica)

Ova datoteka je s projekta Vikimedijina ostava i može se upotrebljavati i na drugim projektima. Ispod su prikazane informacije s njene opisne stranice.

Opis izmjene

Opis
English: A harmonic oscillator in classical mechanics (A-B) and quantum mechanics (C-H). In (A-B), a ball, attached to a spring (gray line), oscillates back and forth. In (C-H), wavefunction solutions to the Time-Dependent Schrödinger Equation are shown for the same potential. The horizontal axis is position, the vertical axis is the real part (blue) or imaginary part (red) of the wavefunction. (C,D,E,F) are stationary states (energy eigenstates), which come from solutions to the Time-Independent Schrodinger Equation. (G-H) are non-stationary states, solutions to the Time-Dependent but not Time-Independent Schrödinger Equation. (G) is a randomly-generated superposition of the four states (E-F). H is a "coherent state" ("Glauber state") which somewhat resembles the classical state B.
العربية: مذبذب توافقي في الميكانيكا الكلاسيكية (A-B) وميكانيكا الكم (C-H). في (A-B)، كرة متصلة بنابض (خط رمادي)، تتأرجح ذهابًا وإيابًا. في (C-H)، يعرض حلول الدالة الموجية لمعادلة شرودنغر المعتمدة على الوقت لنفس الإمكانات. المحور الأفقي هو الموضع، والمحور العمودي هو الجزء الحقيقي (الأزرق) أو الجزء التخيلي (الأحمر) من دالة الموجة. (C ،D ،E ،F) هي حالات ثابتة (حالات الطاقة الذاتية)، والتي تأتي من حلول معادلة شرودنغر المستقلة عن الزمن. (G-H) هي حالات غير ثابتة، وهي حلول لمعادلة شرودنغر التي تعتمد على الوقت ولكنها ليست مستقلة عن الوقت. (G) هو تراكب أنشىء عشوائيًا للحالات الأربع (E-F). H هي "حالة متماسكة" ("حالة جلوبر") تشبه إلى حد ما الحالة الكلاسيكية B.
Datum
Izvor Vlastito djelo
Autor Sbyrnes321 
(* Source code written in Mathematica 6.0 by Steve Byrnes, Feb. 2011. This source code is public domain. *)
(* Shows classical and quantum trajectory animations for a harmonic potential. Assume m=w=hbar=1. *)
ClearAll["Global`*"]
(*** Wavefunctions of the energy eigenstates ***)
psi[n_, x_] := (2^n*n!)^(-1/2)*Pi^(-1/4)*Exp[-x^2/2]*HermiteH[n, x];
energy[n_] := n + 1/2;
psit[n_, x_, t_] := psi[n, x] Exp[-I*energy[n]*t];
(*** A random time-dependent state ***)
SeedRandom[1];
CoefList = Table[Random[]*Exp[2 Pi I Random[]], {n, 0, 4}];
CoefList = CoefList/Norm[CoefList];
Randpsi[x_, t_] := Sum[CoefList[[n + 1]]*psit[n, x, t], {n, 0, 4}];
(*** A coherent state (or "Glauber state") ***)
CoherentState[b_, x_, t_] := Exp[-Abs[b]^2/2] Sum[b^n*(n!)^(-1/2)*psit[n, x, t], {n, 0, 15}];
(*** Make the classical plots...a red ball anchored to the origin by a gray spring. ***)
classical1[t_, max_] := ListPlot[{{max Cos[t], 0}}, PlotStyle -> Directive[Red, AbsolutePointSize[15]]];
zigzag[x_] := Abs[(x + 0.25) - Round[x + 0.25]] - .25;
spring[x_, left_, right_] := (.9 zigzag[3 (x - left)/(right - left)])/(1 + Abs[right - left]);
classical2[t_, max_] := Plot[spring[x, -5, max Cos[t]], {x, -5, max Cos[t]}, PlotStyle -> Directive[Gray, Thick]];
classical3 = ListPlot[{{-5, 0}}, PlotStyle -> Directive[Black, AbsolutePointSize[7]]];
classical[t_, max_, label_] := Show[classical2[t, max], classical1[t, max], classical3, 
   PlotRange -> {{-5, 5}, {-1, 1}}, Ticks -> None, Axes -> {False, True}, PlotLabel -> label, AxesOrigin -> {0, 0}];
(*** Put all the plots together ***)
SetOptions[Plot, {PlotRange -> {-1, 1}, Ticks -> None, PlotStyle -> {Directive[Thick, Blue], Directive[Thick, Pink]}}];
MakeFrame[t_] := GraphicsGrid[
   {{classical[t + 2, 1.5, "A"], classical[t, 3, "B"]},
    {Plot[{Re[psit[0, x, t]], Im[psit[0, x, t]]}, {x, -5, 5}, PlotLabel -> "C"], 
     Plot[{Re[psit[1, x, t]], Im[psit[1, x, t]]}, {x, -5, 5}, PlotLabel -> "D"]},
    {Plot[{Re[psit[2, x, t]], Im[psit[2, x, t]]}, {x, -5, 5}, PlotLabel -> "E"], 
     Plot[{Re[psit[3, x, t]], Im[psit[3, x, t]]}, {x, -5, 5}, PlotLabel -> "F"]},
    {Plot[{Re[Randpsi[x, t]], Im[Randpsi[x, t]]}, {x, -5, 5}, PlotLabel -> "G"], 
     Plot[{Re[CoherentState[1, x, t]], Im[CoherentState[1, x, t]]}, {x, -5, 5}, PlotLabel -> "H"]}
    }, Frame -> All, ImageSize -> 300];
output = Table[MakeFrame[t], {t, 0, 4 Pi*96/97, 4 Pi/97}];
SetDirectory["C:\\Users\\Steve\\Desktop"]
Export["test.gif", output]

Licenciranje

Ja, vlasnik autorskog prava ovog djela, ovdje ga objavljujem pod sljedećom licencom:
Creative Commons CC-Zero Ova datoteka je dostupna pod licencom Creative Commons CC0 1.0 Univerzalnom Posvetom Javne Domene.
Osoba koja je učestvovala u radu na ovom dokumentu posvetila je rad javnoj domeni odricanjem od svih svojih prava na taj rad širom svijeta po zakonu o autorskim pravima i svim povezanim zakonskim pravima koja bi imao/imala, u mjeri dopuštenoj zakonom. Možete kopirati, mijenjati, distribuirati i prilagođavati rad, čak i u komercijalne svrhe, bez traženja dopuštenja.

Opisi

Dodajte objašnjenje u jednom redu što predstavlja ova datoteka

Predmeti pokazani na ovoj datoteci

prikazuje

kreator

Ovo svojstvo ima vrijednost, ali nije poznato

Vikimedija Srpski (transliteracija): Sbyrnes321
URL Bosanski: https://commons.wikimedia.org/wiki/user:Sbyrnes321
skraćeno ime autora Srpski (transliteracija): Sbyrnes321

izvor datoteke Srpski (transliteracija)

sopstveno delo Srpski (transliteracija)

nastanak

27 februar 2011

Historija datoteke

Kliknite na datum/vrijeme da biste vidjeli tadašnju verziju datoteke.

Datum/vrijemeMinijaturaDimenzijeKorisnikKomentar
aktualna11:16, 2 mart 2011Minijatura verzije (11:16, 2 mart 2011)300 × 373 (759 kB)Sbyrnes321Alter spring, to avoid the visual impression that the ball is rotating in a circle around the y-axis through the third dimension.
00:55, 2 mart 2011Minijatura verzije (00:55, 2 mart 2011)300 × 373 (733 kB)Sbyrnes321Add zigzag spring; shrink image to 300px width; increase frame count to 97.
01:58, 28 februar 2011Minijatura verzije (01:58, 28 februar 2011)347 × 432 (707 kB)Sbyrnes321Switched from 100 frames to 80 frames, to be under the 12.5-million-pixel limit for animations in wikipedia articles.
01:06, 28 februar 2011Minijatura verzije (01:06, 28 februar 2011)347 × 432 (887 kB)Sbyrnes321{{Information |Description ={{en|1=A harmonic oscillator in classical mechanics (A-B) and quantum mechanics (C-H). In (A-B), a ball, attached to a spring (gray line), oscillates back and forth. In (C-H), wavefunction solutions to the Time-Dependent Sch

Sljedeća stranica koristi ovu datoteku:

Globalna upotreba datoteke

Ovu datoteku upotrebljavaju i sljedeći projekti:

Potpunija globalna upotreba datoteke

Izvor: https://sh.wikipedia.org/wiki/Datoteka:QuantumHarmonicOscillatorAnimation.gif